cmake_minimum_required(VERSION 3.1)

#------------------------------------------------------------------------------#
# LIBPD PROJECT IN C
#------------------------------------------------------------------------------#
project(libpd C)

#------------------------------------------------------------------------------#
# CMAKE MAC OS SPECIFIC
#------------------------------------------------------------------------------#
set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
set(CMAKE_MACOSX_RPATH ON)
set(CMAKE_OSX_ARCHITECTURES "i386;x86_64")

#------------------------------------------------------------------------------#
# OPTIONS
#------------------------------------------------------------------------------#
option(PD_UTILS "Compile libpd utilities" ON)
option(PD_EXTRA "Compile extras" ON)
option(PD_MULTI "Compile with multiple instance support" OFF)
option(PD_LOCALE "Set the LC_NUMERIC number format to the default C locale" ON)
option(PD_USE_DEFAULT_OUTPUT_DIRECTORY "Use the deault output directory of the build system" OFF)
if(MSVC)
    option(MSVC_STATIC_RUNTIME "Set the runtime library of MSVC" OFF)
    option(MSVC_PTHREAD_LIB "Set the Pthread library to link" "pthread.lib")
endif()

#------------------------------------------------------------------------------#
# OUTPUT DIRECTORY
#------------------------------------------------------------------------------#
if(NOT PD_USE_DEFAULT_OUTPUT_DIRECTORY)
set(CMAKE_SUPPRESS_REGENERATION true)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/libs/)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/libs/)
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/libs/)
foreach(OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES})
    string(TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG)
    set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_SOURCE_DIR}/libs/)
    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_SOURCE_DIR}/libs/)
    set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_SOURCE_DIR}/libs/)
endforeach(OUTPUTCONFIG CMAKE_CONFIGURATION_TYPES)
endif()

#------------------------------------------------------------------------------#
# SOURCES
#------------------------------------------------------------------------------#
set(SOURCE_FILES)

# PURE DATA SOURCES
#------------------------------------------------------------------------------#
file(GLOB PD_SOURCES
    pure-data/src/d_arithmetic.c
    pure-data/src/d_array.c
    pure-data/src/d_ctl.c
    pure-data/src/d_dac.c
    pure-data/src/d_delay.c
    pure-data/src/d_fft.c
    pure-data/src/d_fft_fftsg.c
    pure-data/src/d_filter.c
    pure-data/src/d_global.c
    pure-data/src/d_math.c
    pure-data/src/d_misc.c
    pure-data/src/d_osc.c
    pure-data/src/d_resample.c
    pure-data/src/d_soundfile.c
    pure-data/src/d_ugen.c
    pure-data/src/g_all_guis.c
    pure-data/src/g_all_guis.h
    pure-data/src/g_array.c
    pure-data/src/g_bang.c
    pure-data/src/g_canvas.c
    pure-data/src/g_canvas.h
    pure-data/src/g_clone.c
    pure-data/src/g_editor.c
    pure-data/src/g_graph.c
    pure-data/src/g_guiconnect.c
    pure-data/src/g_hdial.c
    pure-data/src/g_hslider.c
    pure-data/src/g_io.c
    pure-data/src/g_mycanvas.c
    pure-data/src/g_numbox.c
    pure-data/src/g_readwrite.c
    pure-data/src/g_rtext.c
    pure-data/src/g_scalar.c
    pure-data/src/g_template.c
    pure-data/src/g_text.c
    pure-data/src/g_toggle.c
    pure-data/src/g_traversal.c
    pure-data/src/g_vdial.c
    pure-data/src/g_vslider.c
    pure-data/src/g_vumeter.c
    pure-data/src/m_atom.c
    pure-data/src/m_binbuf.c
    pure-data/src/m_class.c
    pure-data/src/m_conf.c
    pure-data/src/m_glob.c
    pure-data/src/m_imp.h
    pure-data/src/m_memory.c
    pure-data/src/m_obj.c
    pure-data/src/m_pd.c
    pure-data/src/m_pd.h
    pure-data/src/m_sched.c
    pure-data/src/s_audio.c
    pure-data/src/s_audio_dummy.c
    pure-data/src/s_inter.c
    pure-data/src/s_loader.c
    pure-data/src/s_main.c
    pure-data/src/s_path.c
    pure-data/src/s_print.c
    pure-data/src/s_stuff.h
    pure-data/src/s_utf8.c
    pure-data/src/s_utf8.h
    pure-data/src/x_acoustics.c
    pure-data/src/x_arithmetic.c
    pure-data/src/x_array.c
    pure-data/src/x_connective.c
    pure-data/src/x_gui.c
    pure-data/src/x_interface.c
    pure-data/src/x_list.c
    pure-data/src/x_midi.c
    pure-data/src/x_misc.c
    pure-data/src/x_net.c
    pure-data/src/x_scalar.c
    pure-data/src/x_text.c
    pure-data/src/x_time.c
    pure-data/src/x_vexp.c
    pure-data/src/x_vexp_fun.c
    pure-data/src/x_vexp_if.c
)
include_directories(pure-data/src)
source_group(pd FILES ${PD_SOURCES})
list(APPEND SOURCE_FILES ${PD_SOURCES})

# PURE DATA EXTRA SOURCES
#------------------------------------------------------------------------------#
if(PD_EXTRA)
    file(GLOB PD_EXTRA_SOURCES
    pure-data/extra/bob~/bob~.c
    pure-data/extra/bonk~/bonk~.c
    pure-data/extra/choice/choice.c
    pure-data/extra/fiddle~/fiddle~.c
    pure-data/extra/loop~/loop~.c
    pure-data/extra/lrshift~/lrshift~.c
    pure-data/extra/pique/pique.c
    pure-data/extra/sigmund~/sigmund~.c
    pure-data/extra/stdout/stdout.c
    )
    include_directories(pure-data/extra)
    source_group(pd/extra FILES ${PD_EXTRA_SOURCES})
    list(APPEND SOURCE_FILES ${PD_EXTRA_SOURCES})
endif()

# LIBPD SOURCES
#------------------------------------------------------------------------------#
file(GLOB LIBPD_SOURCES
    libpd_wrapper/s_libpdmidi.c
    libpd_wrapper/x_libpdreceive.c
    libpd_wrapper/x_libpdreceive.h
    libpd_wrapper/z_hooks.c
    libpd_wrapper/z_hooks.h
    libpd_wrapper/z_libpd.c
)
include_directories(libpd_wrapper)
source_group(libpd FILES ${LIBPD_SOURCES})
list(APPEND SOURCE_FILES ${LIBPD_SOURCES})

# LIBPD UTIL SOURCES
#------------------------------------------------------------------------------#
if(PD_UTILS)
    file(GLOB LIBPD_UTIL_SOURCES
        libpd_wrapper/util/ringbuffer.c
        libpd_wrapper/util/ringbuffer.h
        libpd_wrapper/util/z_print_util.c
        libpd_wrapper/util/z_print_util.h
        libpd_wrapper/util/z_queued.c
        libpd_wrapper/util/z_queued.h
    )
    include_directories(libpd_wrapper/util)
    source_group(libpd/util FILES ${LIBPD_UTIL_SOURCES})
    list(APPEND SOURCE_FILES ${LIBPD_UTIL_SOURCES})
endif()

#------------------------------------------------------------------------------#
# COMPILE DEFINITIONS
#------------------------------------------------------------------------------#
set(LIBPD_COMPILE_DEFINITIONS PD=1 USEAPI_DUMMY=1 PD_INTERNAL=1)

# COMPILE DEFINITIONS OPTIONS
#------------------------------------------------------------------------------#
if(PD_EXTRA)
    list(APPEND LIBPD_COMPILE_DEFINITIONS LIBPD_EXTRA=1)
endif()
if(PD_MULTI)
    list(APPEND LIBPD_COMPILE_DEFINITIONS PDINSTANCE=1 PDTHREADS=1)
endif()
if(NOT PD_LOCALE)
    list(APPEND LIBPD_COMPILE_DEFINITIONS LIBPD_NO_NUMERIC=1)
endif()

# COMPILE DEFINITIONS OS
#------------------------------------------------------------------------------#
if(WIN32)
    list(APPEND LIBPD_COMPILE_DEFINITIONS WINVER=0x502 WIN32=1 _WIN32=1)
    if(${CMAKE_SIZEOF_VOID_P} EQUAL 8)
        list(APPEND LIBPD_COMPILE_DEFINITIONS "PD_LONGINTTYPE=long long")
	endif()
    if(MSVC)
        list(APPEND LIBPD_COMPILE_DEFINITIONS HAVE_STRUCT_TIMESPEC=1 _CRT_SECURE_NO_WARNINGS=1)
    endif()
elseif(UNIX)
    list(APPEND LIBPD_COMPILE_DEFINITIONS HAVE_LIBDL=1 HAVE_UNISTD_H=1)
endif()


#------------------------------------------------------------------------------#
# C FLAGS
#------------------------------------------------------------------------------#

# C FLAGS COMPILER OR GENERATOR
#------------------------------------------------------------------------------#
if(CMAKE_GENERATOR STREQUAL Xcode)
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-variable -Wno-unused-function")
    set(CMAKE_C_FLAGS_RELEASE "-fomit-frame-pointer")
elseif(MSVC)
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W3 /wd4005 /wd4091 /wd4100 /wd4133 /wd4102 /wd4267 /wd4311 /wd4477 /wd4996")
    if(MSVC_STATIC_RUNTIME)
        foreach(RFLAG CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
            if(${RFLAG} MATCHES "/MD")
                string(REGEX REPLACE "/MD" "/MT" ${RFLAG} "${${RFLAG}}")
            endif()
        endforeach()
    endif()

elseif(CMAKE_C_COMPILER_ID STREQUAL GNU)
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-variable -fPIC")
    set(CMAKE_C_FLAGS_RELEASE "-ffast-math -funroll-loops -fomit-frame-pointer -O3")
elseif(CMAKE_C_COMPILER_ID STREQUAL Clang)
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-variable")
    set(CMAKE_C_FLAGS_RELEASE "-ffast-math -funroll-loops -fomit-frame-pointer -O3")
endif()

#------------------------------------------------------------------------------#
# TARGETS
#------------------------------------------------------------------------------#
add_library(libpdshared SHARED ${SOURCE_FILES})
add_library(libpdstatic STATIC ${SOURCE_FILES})
target_compile_definitions(libpdshared PUBLIC ${LIBPD_COMPILE_DEFINITIONS})
target_compile_definitions(libpdstatic PUBLIC ${LIBPD_COMPILE_DEFINITIONS})
target_compile_definitions(libpdstatic PUBLIC PTW32_STATIC_LIB=1)

#------------------------------------------------------------------------------#
# GENERATOR OPTIONS
#------------------------------------------------------------------------------#
if(CMAKE_GENERATOR STREQUAL Xcode)
    set_target_properties(libpdstatic PROPERTIES GCC_WARN_UNUSED_VARIABLE False)
    set_target_properties(libpdshared PROPERTIES GCC_WARN_UNUSED_VARIABLE False)

    set_target_properties(libpdstatic PROPERTIES XCODE_ATTRIBUTE_LLVM_LTO[variant=Release] True)
    set_target_properties(libpdshared PROPERTIES XCODE_ATTRIBUTE_LLVM_LTO[variant=Release] True)
    set_target_properties(libpdstatic PROPERTIES GCC_OPTIMIZATION_LEVEL[variant=Release] 3)
    set_target_properties(libpdshared PROPERTIES GCC_OPTIMIZATION_LEVEL[variant=Release] 3)
    set_target_properties(libpdstatic PROPERTIES GCC_UNROLL_LOOPS[variant=Release] True)
    set_target_properties(libpdshared PROPERTIES GCC_UNROLL_LOOPS[variant=Release] True)
    set_target_properties(libpdstatic PROPERTIES GCC_FAST_MATH[variant=Release] True)
    set_target_properties(libpdshared PROPERTIES GCC_FAST_MATH[variant=Release] True)
endif()

#------------------------------------------------------------------------------#
# LINK
#------------------------------------------------------------------------------#

# LINK OS
#------------------------------------------------------------------------------#
if(WIN32)
	target_link_libraries(libpdshared ws2_32)
	target_link_libraries(libpdstatic ws2_32)
else("${CMAKE_SYSTEM}" MATCHES "Linux")
    find_library(MATH_LIB m)
	target_link_libraries(libpdstatic ${MATH_LIB})
	target_link_libraries(libpdstatic ${CMAKE_DL_LIBS})
	target_link_libraries(libpdshared ${MATH_LIB})
	target_link_libraries(libpdshared ${CMAKE_DL_LIBS})
endif()

# LINK PTHREAD
#------------------------------------------------------------------------------#
set(THREADS_PREFER_PTHREAD_FLAG On)
set(CMAKE_THREAD_PREFER_PTHREAD True)
find_package(Threads REQUIRED)
target_link_libraries(libpdshared Threads::Threads)
target_link_libraries(libpdstatic Threads::Threads)
if(MSVC)
    link_directories(${PROJECT_SOURCE_DIR}/pure-data)
    target_link_libraries(libpdshared ${MSVC_PTHREAD_LIB})
    target_link_libraries(libpdstatic ${MSVC_PTHREAD_LIB})
endif()

#------------------------------------------------------------------------------#
# OUTPUT NAME
#------------------------------------------------------------------------------#
if(WIN32)
    if(PD_MULTI)
        set_target_properties(libpdshared PROPERTIES OUTPUT_NAME libpd-multi)
    	set_target_properties(libpdstatic PROPERTIES OUTPUT_NAME libpd-multi-static)
    else()
        set_target_properties(libpdshared PROPERTIES OUTPUT_NAME libpd)
    	set_target_properties(libpdstatic PROPERTIES OUTPUT_NAME libpd-static)
    endif()
else()
    if(PD_MULTI)
        set_target_properties(libpdshared PROPERTIES OUTPUT_NAME pd-multi)
    	set_target_properties(libpdstatic PROPERTIES OUTPUT_NAME pd-multi)
    else()
        set_target_properties(libpdshared PROPERTIES OUTPUT_NAME pd)
    	set_target_properties(libpdstatic PROPERTIES OUTPUT_NAME pd)
    endif()
endif()
